Jump to content
43oh

How to implement Timer interruption in Energia?


Recommended Posts

Hello,everyone!

I meet a problem, when I want to realize a Heart Rate detection program which is written in arduino. I have two questions:

1.how to implement Timer interruption in Energia?

2.what is the clock source of msp430fr5969 launchpad?Should I solder an external crystal on it?

At last, I put the arduino program as the attach files.PulseSensorAmped_Arduino_1dot2.rar

Link to post
Share on other sites

Look in wiring.c (in energia - hardware\msp430\cores\msp430 ) to be sure you don't reprogram one of the timers that 

Energia uses internally.  (Might also want to check Tone.cpp TimerSerial.cpp and Servo library - to be sure you don't use

a timer that already used).

 

http://webcache.googleusercontent.com/search?q=cache:http://coder-tronics.com/msp430-timer-pwm-tutorial/

 

http://www.embeddedrelated.com/showarticle/182.php

 

http://homepages.ius.edu/RWISMAN/C335/HTML/msp430Timer.HTM

Link to post
Share on other sites

Look in wiring.c (in energia - hardware\msp430\cores\msp430 ) to be sure you don't reprogram one of the timers that 

Energia uses internally.  (Might also want to check Tone.cpp TimerSerial.cpp and Servo library - to be sure you don't use

a timer that already used).

 

http://webcache.googleusercontent.com/search?q=cache:http://coder-tronics.com/msp430-timer-pwm-tutorial/

 

http://www.embeddedrelated.com/showarticle/182.php

 

http://homepages.ius.edu/RWISMAN/C335/HTML/msp430Timer.HTM

Thank you for your kind advise.

But now, I meet a problem, I don't know how to write a Timer ISR in energia. I have searched for some examples of CCS in which the ISR can be written like this:

"#pragma vector = TIMER0_A0_VECTOR

_interrupt void Timer0_A0_ISR (void)"
While I find it can't work in energia, can you tell me how to write an ISR function in energia?
Thank you !
Link to post
Share on other sites

As a side note, check out this library I wrote - https://github.com/spirilis/RTC_B

This implements an interface to the RTC_B peripheral (Real Time Clock) present on the FR5969 chip.  It has a feature for periodic interruption, called rtc.attachPeriodicInterrupt()

 

If you use the library to actually *set* the time, you can also make use of the alarm - rtc.attachScheduledInterrupt()

 

Implementing Timer ISRs is generally frowned upon in Energia because Energia claims them for PWM, but the FR5969 has a Timer_A instance# 2 and 3 which are not used for PWM at all, and they can be commandeered for your own purposes.

Link to post
Share on other sites

As a side note, check out this library I wrote - https://github.com/spirilis/RTC_B

This implements an interface to the RTC_B peripheral (Real Time Clock) present on the FR5969 chip.  It has a feature for periodic interruption, called rtc.attachPeriodicInterrupt()

 

If you use the library to actually *set* the time, you can also make use of the alarm - rtc.attachScheduledInterrupt()

 

Implementing Timer ISRs is generally frowned upon in Energia because Energia claims them for PWM, but the FR5969 has a Timer_A instance# 2 and 3 which are not used for PWM at all, and they can be commandeered for your own purposes.

Thank you for your suggestions!

I have looked over the RTC_B driver and found it useful to creat a ~2ms periodic interruption. After modification, the program still can't work out and the error hint " lvalue required as left operand of assignment"  is ambiguous.

My code is here:




/*
>> Pulse Sensor Amped 1.2 <<
This code is for Pulse Sensor Amped by Joel Murphy and Yury Gitman
    www.pulsesensor.com 
    >>> Pulse Sensor purple wire goes to Analog Pin 0 <<<
Pulse Sensor sample aquisition and processing happens in the background via Timer 2 interrupt. 2mS sample rate.
PWM on pins 3 and 11 will not work when using this code, because we are using Timer 2!
The following variables are automatically updated:
Signal :    int that holds the analog signal data straight from the sensor. updated every 2mS.
IBI  :      int that holds the time interval between beats. 2mS resolution.
BPM  :      int that holds the heart rate value, derived every beat, from averaging previous 10 IBI values.
QS  :       boolean that is made true whenever Pulse is found and BPM is updated. User must reset.
Pulse :     boolean that is true when a heartbeat is sensed then false in time with pin13 LED going out.

This code is designed with output serial data to Processing sketch "PulseSensorAmped_Processing-xx"
The Processing sketch is a simple data visualizer. 
All the work to find the heartbeat and determine the heartrate happens in the code below.
Pin 13 LED will blink with heartbeat.
If you want to use pin 13 for something else, adjust the interrupt handler
It will also fade an LED on pin fadePin with every beat. Put an LED and series resistor from fadePin to GND.
Check here for detailed code walkthrough:
http://pulsesensor.myshopify.com/pages/pulse-sensor-amped-arduino-v1dot1

Code Version 1.2 by Joel Murphy & Yury Gitman  Spring 2013
This update fixes the firstBeat and secondBeat flag usage so that realistic BPM is reported.

*/

#include <RTC_B.h>
//  VARIABLES
int pulsePin = 0;                 // Pulse Sensor purple wire connected to analog pin 0
int blinkPin = 13;                // pin to blink led at each beat
int fadePin = 5;                  // pin to do fancy classy fading blink at each beat
int fadeRate = 0;                 // used to fade LED on with PWM on fadePin


// these variables are volatile because they are used during the interrupt service routine!
volatile int BPM;                   // used to hold the pulse rate
volatile int Signal;                // holds the incoming raw data
volatile int IBI = 600;             // holds the time between beats, must be seeded! 
volatile boolean Pulse = false;     // true when pulse wave is high, false when it's low
volatile boolean QS = false;        // becomes true when Arduoino finds a beat.

volatile int rate[10];                    // array to hold last ten IBI values
volatile unsigned long sampleCounter = 0;          // used to determine pulse timing
volatile unsigned long lastBeatTime = 0;           // used to find IBI
volatile int P =512;                      // used to find peak in pulse wave, seeded
volatile int T = 512;                     // used to find trough in pulse wave, seeded
volatile int thresh = 512;                // used to find instant moment of heart beat, seeded
volatile int amp = 100;                   // used to hold amplitude of pulse waveform, seeded
volatile boolean firstBeat = true;        // used to seed rate array so we startup with reasonable BPM
volatile boolean secondBeat = false;      // used to seed rate array so we startup with reasonable BPM

void setup(){
  boolean t;
  pinMode(blinkPin,OUTPUT);         // pin that will blink to your heartbeat!
  pinMode(fadePin,OUTPUT);          // pin that will fade to your heartbeat!
  Serial.begin(115200);             // we agree to talk fast!
  rtc.begin();                 // sets up to read Pulse Sensor signal every 2mS 
  t = rtc.attachPeriodicInterrupt(500,timer_do);  // Runs RTC_ISR() every 2mS
  if (!t) {
    Serial.println("ERROR: Could not register a 2ms Periodic Interrupt!");
  }
   // UN-COMMENT THE NEXT LINE IF YOU ARE POWERING The Pulse Sensor AT LOW VOLTAGE, 
   // AND APPLY THAT VOLTAGE TO THE A-REF PIN
   //analogReference(EXTERNAL);   
}



void loop(){
  sendDataToProcessing('S', Signal);     // send Processing the raw Pulse Sensor data
  if (QS == true){                       // Quantified Self flag is true when arduino finds a heartbeat
        fadeRate = 255;                  // Set 'fadeRate' Variable to 255 to fade LED with pulse
        sendDataToProcessing('B',BPM);   // send heart rate with a 'B' prefix
        sendDataToProcessing('Q',IBI);   // send time between beats with a 'Q' prefix
        QS = false;                      // reset the Quantified Self flag for next time    
     }
  
  ledFadeToBeat();
  
  delay(20);                             //  take a break
}


void ledFadeToBeat(){
    fadeRate -= 15;                         //  set LED fade value
    fadeRate = constrain(fadeRate,0,255);   //  keep LED fade value from going into negative numbers!
    analogWrite(fadePin,fadeRate);          //  fade LED
  }


void sendDataToProcessing(char symbol, int data ){
    Serial.print(symbol);                // symbol prefix tells Processing what type of data is coming
    Serial.println(data);                // the data to send culminating in a carriage return
  }

// THIS IS THE TIMER 2 INTERRUPT SERVICE ROUTINE. 
// Timer 2 makes sure that we take a reading every 2 miliseconds
 void timer_do(){                        // triggered when Timer2 counts to 124
 // noInterrupts();                                      // disable interrupts while we do this
  Signal = analogRead(pulsePin);              // read the Pulse Sensor 
  sampleCounter += 2;                         // keep track of the time in mS with this variable
  int N = sampleCounter - lastBeatTime;       // monitor the time since the last beat to avoid noise

    //  find the peak and trough of the pulse wave
  if(Signal < thresh && N > (IBI/5)*3){       // avoid dichrotic noise by waiting 3/5 of last IBI
    if (Signal < T){                        // T is the trough
      T = Signal;                         // keep track of lowest point in pulse wave 
    }
  }

  if(Signal > thresh && Signal > P){          // thresh condition helps avoid noise
    P = Signal;                             // P is the peak
  }                                        // keep track of highest point in pulse wave

  //  NOW IT'S TIME TO LOOK FOR THE HEART BEAT
  // signal surges up in value every time there is a pulse
  if (N > 250){                                   // avoid high frequency noise
    if ( (Signal > thresh) && (Pulse == false) && (N > (IBI/5)*3) ){        
      Pulse = true;                               // set the Pulse flag when we think there is a pulse
      digitalWrite(blinkPin,HIGH);                // turn on pin 13 LED
      IBI = sampleCounter - lastBeatTime;         // measure time between beats in mS
      lastBeatTime = sampleCounter;               // keep track of time for next pulse

      if(secondBeat){                        // if this is the second beat, if secondBeat == TRUE
        secondBeat = false;                  // clear secondBeat flag
        for(int i=0; i<=9; i++){             // seed the running total to get a realisitic BPM at startup
          rate[i] = IBI;                      
        }
      }

      if(firstBeat){                         // if it's the first time we found a beat, if firstBeat == TRUE
        firstBeat = false;                   // clear firstBeat flag
        secondBeat = true;                   // set the second beat flag
      //  interrupts();                               // enable interrupts again
        return;                              // IBI value is unreliable so discard it
      }   


      // keep a running total of the last 10 IBI values
      word runningTotal = 0;                  // clear the runningTotal variable    

      for(int i=0; i<=8; i++){                // shift data in the rate array
        rate[i] = rate[i+1];                  // and drop the oldest IBI value 
        runningTotal += rate[i];              // add up the 9 oldest IBI values
      }

      rate[9] = IBI;                          // add the latest IBI to the rate array
      runningTotal += rate[9];                // add the latest IBI to runningTotal
      runningTotal /= 10;                     // average the last 10 IBI values 
      BPM = 60000/runningTotal;               // how many beats can fit into a minute? that's BPM!
      QS = true;                              // set Quantified Self flag 
      // QS FLAG IS NOT CLEARED INSIDE THIS ISR
    }                       
  }

  if (Signal < thresh && Pulse == true){   // when the values are going down, the beat is over
    digitalWrite(blinkPin,LOW);            // turn off pin 13 LED
    Pulse = false;                         // reset the Pulse flag so we can do it again
    amp = P - T;                           // get amplitude of the pulse wave
    thresh = amp/2 + T;                    // set thresh at 50% of the amplitude
    P = thresh;                            // reset these for next time
    T = thresh;
  }

  if (N > 2500){                           // if 2.5 seconds go by without a beat
    thresh = 512;                          // set thresh default
    P = 512;                               // set P default
    T = 512;                               // set T default
    lastBeatTime = sampleCounter;          // bring the lastBeatTime up to date        
    firstBeat = true;                      // set these to avoid noise
    secondBeat = false;                    // when we get the heartbeat back
  }

  //interrupts();                                   // enable interrupts when youre done!
}// end isr




 

If available, please figure out my faults.Thanks again.

Link to post
Share on other sites

The error will almost certainly be on line 107. Recall that TI's headers define single-character macros that inconveniently interfere with variable declarations:

/************************************************************
* STATUS REGISTER BITS
************************************************************/

#define C                   (0x0001)
#define Z                   (0x0002)
#define N                   (0x0004)
#define V                   (0x0100)
As a general rule, don't use fully capitalized symbols for variable names, and particularly not single-letter ones.
Link to post
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Reply to this topic...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
×
  • Create New...